wpfXamlEditor

Overview

XamlEditor is a Xaml editor for an APL variable or for a file on disk.

This Dyalog APL user command is able to show the Xaml in color with folding, to print it and to reorganize it so it is more readable according to some settings set by the user. It is inspired by the work of Robby Ingebretsen of Kaxaml (http://www.Kaxaml.com). It is particularly valuable for APLers that like to keep their Xaml in the workspace. With XamlEditor they have a tool to maintain it without effort.

Usage

Once installed the user command can be invoked by typing ]XamlEditor (casing is not important, no argument). The following start-up screen will appear:

Here is a short description of each button:

Button	Explanation	Button	Explanation
	Execute the Xaml and show the result in a separate window		Select all the Xaml
	Rewrite the Xaml according to the settings (Scrub)		Delete the selected text
	Open a dialog box to select a Xaml variable in the WS		Clear the clipboard
	Open a dialog box to save the Xaml as a variable in the WS		Undo last operation
	Open a dialog box to select a file on disk		Redo previous operation
	Open a dialog box to save the Xaml to a file		Print all the Xaml
	Cut the Selected Text to The Clipboard		Print preview all the Xaml
	Copy the selected text to the clipboard		Make selected text a comment
	Paste the text from the clipboard		Choose the settings when scrubbing

Installation

Download the file wpfXamlEditor.1.1.zip. It contains the Dyalog user command file wpfXamlEditor.dyalog and a dll named ICSharpCode.AvalonEdit.dll
Copy the file wpfXamlEditor.dyalog to your user command directory (for advice how to organize your User Commands see UserCommands/WhereShouldTheyGo).
Copy the file ICSharpCode.AvalonEdit.dll to the same directory as your dyalog.exe file (as shown by +2 ⎕NQ'.' 'GetEnvironment' 'Dyalog'). You may need administrator privileges for copying the file. That dll is free of charge and was written by Daniel Grunwald. It can be downloaded from CodeProject or from AvalonEdit but is included in the zip file for commodity.

Detailed Explanations

Execute the Xaml and Show the Result in a Separate Window

The Xaml will be parsed and shown in a separate window. If the root element of the Xaml is not a window it will be made the content of a new window. The x:Class attribute will be removed if present. All the events will be removed before parsing the Xaml by the function ScrubAndFix. It does not rely on a prefix to removed the events. ( ( Show ScrubAndFix Hide ScrubAndFix ) )

   ∇ rootObj←ScrubAndFix xamlString;err;reader;stringReader;writer;⎕USING
     ⍝ Function to remove the Class and Events elements of Xaml and fix the resulting Xaml.
     ⍝ This function is most usefull when experimenting with Xaml taken directly from the Web but is slower than FixXaml.
     ⍝ Inspired from the code of XAMLPAD2009.
     ⍝
     ⍝ XamlString = Vector of Characters representing a XAML string
     ⍝ rootObj    = WPF Root Element Object if no error
     ⍝            = ⎕NULL (explanation of error) if error

      :Trap 0

          ⎕USING←'System.IO' 'System.Windows.Markup,WPF/PresentationFramework.dll' 'System.Xaml,System.Xaml.dll'
          stringReader←⎕NEW StringReader(⊂xamlString)
          reader←⎕NEW XamlXmlReader(stringReader XamlReader.GetWpfSchemaContext)
          writer←⎕NEW XamlObjectWriter(reader.SchemaContext)

          ⎕USING←0⍴⊂'' ⍝ Don't need it anymore

          :While reader.Read

              :If 'StartMember'≡⍕reader.NodeType
              :AndIf reader.Member.Name≡'Class'
                ⍝ Skip the x:Class attribute
                  {}reader.Read
                  {}reader.Read

              :ElseIf 'StartMember'≡⍕reader.NodeType
              :AndIf reader.Member.IsEvent
                ⍝ Skip the Event member
                  {}reader.Read
                  {}reader.Read

              :Else
                ⍝ Keep the other nodes
                  writer.WriteNode(reader)

              :End

          :EndWhile

        ⍝ The following line will return the root object
          rootObj←writer.Result

      :Else
         ⍝ Build the Error Message
          :If 90≠⎕EN
            ⍝ APL Error
              err←(1⊃⎕DM),': ',{(' '=1↑⍵)↓((1↓a,0)∨a←' '≠⍵)/⍵}(2⊃⎕DM),(⎕UCS 13)

          :Else
            ⍝ .Net Error
              :Trap 0
                ⍝ Show the value of ⎕EXCEPTION.Message if not ⎕NULL.
                  err←('EXCEPTION: ',⎕EXCEPTION.Message),(⎕UCS 13)
              :Else
                ⍝ Sometimes ⎕EXCEPTION is (NULL) and will bug here.
                  err←'Exception (NULL): Unknown error',(⎕UCS 13)

              :EndTrap

          :End

          rootObj←⎕NULL err

      :EndTrap
    ∇

Rewrite the Xaml according to the settings (Scrub)

Will rewrite the Xaml according to the settings. The most important setting is Attribute Tolerance; it allows you to define how many attributes there could be on one line of Xaml. Past that number all the attributes are written on a separate line.

	Open a dialog box to select a Xaml variable in the WS
	Open a dialog box to save the Xaml as a variable in the WS

The dialog box contains a tree element where each branch is a namespace that has a character variable that responds positive to the following test: do the first and last character match '<>' after removing the white space (space,LF,NL,HT characters)? In APL:

'><'≡¯2↑1⌽variableName~⎕UCS 32 10 13 9

Note that variables of scripted namespaces will not be permanently changed by XamlEditor.

	Open a dialog box to select a file on disk
	Open a dialog box to save the Xaml to a file

A standard OpenFileDialog and SaveFileDialog are used to select and save the file.

	Print all the Xaml
	Print preview all the Xaml

Will take the Xaml to a FlowDocument where it can be previewed or printed directly.

Make selected text a comment

The following rules apply to this button when clicked:

If nothing is selected it will insert '' at the caret.
If the selection is positive to the test: ' --><!-- '≡9↑¯4⌽selectedText, the comments are removed.
Otherwise it will insert: ''

Choose the Settings when scrubbing

The settings for scrubbing are saved in an XML file named XED.Settings.xml. The file will be created automatically with default values the first time the user command runs.

It will be located in the AppData directory. The data of the file looks like this:

   1 <Settings>
   2   <EditorFont>APL385 Unicode</EditorFont>
   3   <EditorFontSize>14</EditorFontSize>
   4   <ReducePrecision>1</ReducePrecision>
   5   <Precision>3</Precision>
   6   <AttributeCounteTolerance>3</AttributeCounteTolerance>
   7   <ReorderAttributes>1</ReorderAttributes>
   8   <RemoveCommonDefaultValues>0</RemoveCommonDefaultValues>
   9   <ConvertTabsToSpaces>1</ConvertTabsToSpaces>
  10   <SpaceCount>3</SpaceCount>
  11 </Settings>

It is used to populate the "Settings" window.

Item	Description
"Font"	Font used by Xaml Editor
"Font Size"	Size of the font used by Xaml Editor
"Numeric Precision"	Reduce the precision of large numbers to a maximum of this number of digits beyond the decimal point
"Attribute Tolerance"	If more than this number of attributes are defined on an element, Scrubber will move each attribute onto its own line
"Reorder Attributes By Importance"	Scrubber will reorder attributes on a given element according to a predetermined set of rules about which attributes are most important
"Remove Common Default Values"	Scrubber will remove common properties which are being set to their default values
"Indent Using Spaces"	If this is checked Scrubber will indent using spaces instead of tabs

Version Information

Version 1.0 Mars 2015

Version 1.1 February 2016
        SaveSettings and GetSettings changed to always use the AppData directory
        Initial focus is now set to the editor instead of the window (via Xaml)

Original author:	Pierre Gilbert
Responsible:	PierreGilbert
Email:	`<apgil AT SPAMFREE videotron DOT ca>`

CategoryDyalog - CategoryDyalogDotNet - CategoryDyalogWpfUtilities - CategoryDotNet